# $Id: PKGBUILD 17998 2010-05-29 05:58:37Z ebelanger $
# Maintainer: Eric Belanger <eric@archlinux.org>
# Contributor: tranquility <trankas@gmail.com>

pkgname=lincity-ng
pkgver=2.0
pkgrel=3
pkgdesc="A City Simulation Game. It is a polished and improved version of the classic LinCity game"
arch=('i686' 'x86_64')
url="http://lincity-ng.berlios.de/wiki/index.php/Main_Page"
license=('GPL' 'custom')
depends=('sdl_mixer' 'sdl_ttf' 'sdl_image' 'physfs' 'libxml2' 'sdl_gfx' 'gcc-libs' 'libgl')
makedepends=('ftjam' 'mesa')
source=(http://download.berlios.de/lincity-ng/${pkgname}-${pkgver}.tar.bz2)
md5sums=('1bd0f58e0f2b131d70044f4230600ed1')
sha1sums=('2961a3f60f7481b33858d7d5ef7cf9c788d01077')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr || return 1
  jam || return 1
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  jam -sprefix="${pkgdir}/usr" install || return 1
  install -D -m644 COPYING-data.txt "${pkgdir}/usr/share/licenses/${pkgname}/COPYING-data.txt" || return 1
  install -D -m644 COPYING-fonts.txt "${pkgdir}/usr/share/licenses/${pkgname}/COPYING-fonts.txt" || return 1
}