# $Id: PKGBUILD 37973 2011-01-19 13:19:20Z andrea $
# Maintainer: Ray Rashif <schiv@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Geoffroy Carrier <geoffroy.carrier@koon.fr>
# Contributor: Thomas Jost <thomas.jost@gmail.com>

pkgname=subdownloader
pkgver=2.0.14
pkgrel=2
pkgdesc="Automatic download/upload of subtitles using fast hashing"
arch=('any')
url="http://www.subdownloader.net/"
license=('GPL3')
depends=('imdbpy' 'kaa-metadata' 'python2-qt')
source=(http://launchpad.net/$pkgname/trunk/$pkgver/+download/$pkgname-$pkgver.tar.gz)
md5sums=('b60443cfcefd89b0893628b18eccae9c')

package() {
  cd "$srcdir/$pkgname-$pkgver"

  # python2 fix
  for file in $(find . -name '*.py' -print); do
    sed -i 's_^#!.*/usr/bin/python_#!/usr/bin/python2_' $file
    sed -i 's_^#!.*/usr/bin/env.*python_#!/usr/bin/env python2_' $file
  done

  # prepare dirs
  install -d "$pkgdir/usr/share/$pkgname" \
    "$pkgdir/usr/bin" \
    "$pkgdir/usr/share/man/man1/"

  # manuals
  gzip subdownloader.1
  install -D subdownloader.1.gz "$pkgdir/usr/share/man/man1/"

  # freedesktop.org
  install -D -m644 subdownloader.desktop \
    "$pkgdir/usr/share/applications/subdownloader.desktop"
  rm subdownloader.1.gz subdownloader.desktop

  # runtime and executables
  cp -a * "$pkgdir/usr/share/$pkgname/"
  chmod 755 "$pkgdir/usr/share/$pkgname/run.py"
  ln -s "/usr/share/$pkgname/run.py" \
    "$pkgdir/usr/bin/subdownloader"

  install -D -m644 gui/images/subdownloader.png \
    "$pkgdir/usr/share/pixmaps/subdownloader.png"
}

# vim:set ts=2 sw=2 et: