# $Id: PKGBUILD 34010 2010-11-30 21:13:21Z lcarlier $
# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Kessia 'even' Pinheiro <kessiapinheiro at gmail.com>

pkgname=gufw
_realname=gui-ufw
pkgver=10.10
_pkgvermain=10.10.1
pkgrel=2
pkgdesc="An easy, intuitive way to manage your Linux firewall"
arch=('any')
url="http://gufw.tuxfamily.org/index.html"
license=('GPL3')
depends=('ufw' 'pygtk' 'sudo' 'gksu')
makedepends=('patch')
changelog=$pkgname.changelog
source=(https://launchpad.net/ubuntu/maverick/+source/${_realname}/${_pkgvermain}-0ubuntu1/+files/${_realname}_${_pkgvermain}.orig.tar.gz \
        $pkgname-$pkgver-execute.patch)
install=$pkgname.install
md5sums=('c80491c1c591572b061746b9ab5f5f7a'
         '664ba069775be88e36c50f75d6b7892d')

build() {
  cd ${srcdir}/${_realname}-${_pkgvermain}

  # python2 fix
  for file in $(find . -name '*.py' -print); do
      sed -i 's_#!.*/usr/bin/python_#!/usr/bin/python2_' $file
      sed -i 's_#!.*/usr/bin/env.*python_#!/usr/bin/env python2_' $file
  done

  python2 setup.py build install --root=${pkgdir}

  cd ${pkgdir}
  patch -Np0 -i ${srcdir}/$pkgname-$pkgver-execute.patch
}